home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d3 / amac36.arc / MACR28.QM < prev    next >
Text File  |  1991-03-16  |  35KB  |  757 lines
  1. *                      (MacroMaker)  MACR28.QM
  2. * ┌────────────────────────[ (Index) of Macros ]───────────────────────────────┐
  3. * │(Alt_2) - Refresh with "standard" macfile
  4. * │(Alt_3) - Merges current macros with designated txtfile, reads macfile
  5. * │(Alt_4) - Appends txtfile to "standard" txtfile & macfile, reads macfile
  6. * │(Alt_5) - Gets error files in window
  7. * │(Alt_6) - Makes dummy txtfile from current macros
  8. * │(Alt_7) - Makes & reads dummy macfile from txtfile
  9. * │(Alt_t) - Makes & reads dummy macfile from txtfile, SMALL
  10. * │(Alt_8) - Reads macfile of txtfile
  11. * │(Alt_9) - Makes macfile only of txtfile
  12. * │(Alt_0) - Makes & reads macfile of txtfile
  13. * │(Alt_q) - Makes & reads macfile of txtfile, SMALL
  14. * │
  15. * │(Alt_f1)- Makes single column macro
  16. * │(Alt_f2)- Puts command key beside a single command in a macro <- chg
  17. * │(Alt_f3)- Puts command key beside ALL commands in a macro     <- chg
  18. * │(Alt_f4)- Gets a single command and it's key on screen        <- chg
  19. * │
  20. * │(Alt_h)   Select Index item with cursor line, then <enter>.
  21. * │
  22. * │(Index) Use      - How to locate macro or item from Index using @h
  23. * │(Description)    - MacroMaker Macros
  24. * │(Requirements)   - and use
  25. * │(Startup)        - See MACR.DOC for startup instructions
  26. * │(Macros)         - MacroMaker Macros
  27. * │(Other) Macros   - not included
  28. * │(Version) history
  29. * └────────[ be sure to leave at least one blank line at end of Index ]────────┘
  30.  
  31.  
  32. * (Index) Use;
  33. *
  34. * To locate a macro or item in this file, press @h, place the cursor
  35. * line on the desired item in the Index above, and press <enter>.
  36. * See BOOK15.QM for more details.
  37.  
  38. * (Description):
  39.  
  40. * (MacroMaker) MACR28.ZIP Contains QEdit macros to easily convert
  41. * macros to & from text/binary (txtfile/macfile) using QMAC macro
  42. * translator:
  43.  
  44.  
  45. * (Requirements) and Use (see MACR.DOC for (startup) instructions):
  46. *
  47. *         1. Txtfile name extension MUST be [file].QM, Macfile [file].MAC.
  48. *         2. Change ram disk c:\ (also in batch files) for your setup.
  49. *            Ram disk is optional but faster than a hard drive. Use any
  50. *            active drive letter to replace c:\.
  51. *         3. Batch files must be in path or current directory. INSERT must
  52. *            be ON. Run macros and press Enter to continue when paused.
  53. *         4. Modify "g:\qe\MACROS.xxx" in macros to your "standard" macro.
  54. *            Be careful to use or not use extension as shown, with spaces.
  55. *         5. Be sure to change "g:\qe\qconfig.dat" in the macros @f2 -
  56. *            @f4 below to the location of your qconfig.dat in your
  57. *            setup, and convert with QMAC.
  58.  
  59. * In order for macros @f2 - @f4 to find a command in QCONFIG.DAT, there
  60. * must be at least eight blank spaces betweeen the end of the command   | 2.8
  61. * key and the beginning of the command. If your QCONFIG.DAT has fewer
  62. * spaces, the macros must be modified in the first 'FIND' line.
  63.  
  64. * Insert must be ON.
  65.  
  66. * Replacing C:\ with a ram drive will make the macros run considerably
  67. * faster.
  68.  
  69. * These macros require "QEdit and QMAC v2.1, February, 1990" or later.
  70. *
  71. * To BEGIN, just type "START MACR" <Enter>. All pertinent files will be
  72. * loaded in the "Ring" for viewing, and MACR28.MAC is read.
  73. * Alternatively, type "START MACR 0" <Enter> and the disk copies of all
  74. * files in the "Ring" will be loaded ready for editing, saving time.
  75.  
  76.  
  77.  
  78.  
  79.  
  80. * --------------------------(Macros)---------------------------------
  81. *
  82. *┌───────────────────────────────────────────────────────────┐
  83. *│(Alt_2) Refreshes macro buffer with "standard" macfile     │
  84. *└───────────────────────────────────────────────────────────┘
  85. * Remember to modify "g:\qe\macros.mac" with your "standard" macfile.
  86. *
  87. @2 MacroBegin MacroRead "g:\qe\macros.mac" Return
  88. *
  89. * 38 bytes Thu  07-26-1990  02:16:58
  90. * 38 bytes Fri  09-14-1990  14:05:43
  91.  
  92.  
  93.  
  94.  
  95. *┌────────────────────────────────────────────────────────────────┐
  96. *│(Alt_3) Merges designated txtfile [file].qm with current macros │
  97. *└────────────────────────────────────────────────────────────────┘
  98. *
  99. @3 macrobegin
  100.    editfile "c:$" return killfile quit                       * gets macro to
  101.    editfile       return return                              *  be merged with
  102.    "Merge macro ? "return cursorup endline cursorright pause *  
  103.    cursorleft markword cut killfile quit                     *                     *
  104.    macrowrite "dum4.mac" return  return                      * write cur macros
  105.    DOS "qmacM " paste return return                          * makes apnd macro
  106.    horizontalwindow                                          *
  107.    editfile "c:!" return quit editfile       return          * get error file
  108.    insertdate  inserttime                                    * put date in c:!
  109.    find "(" return return
  110.  jfalse NOERROR:                                             * get error line #
  111.    wordright unmarkblock markblockbegin wordright            *
  112.    cursorleft markblockend copy savefile prevwindow          *
  113.    gotoline paste return makectrofscreen pause zoomwindow    * go to error #1
  114.  jump CONTINUE:                                              *
  115.  NOERROR:
  116.    prevwindow zoomwindow                                     * no error, back
  117.  CONTINUE:
  118.    editfile "dum4.qm" return                                 * load apnd. txtfil
  119.    splitline newfile "N" return endfile return               *
  120.   "*...Tom Hogshead " insertdate inserttime                  * stamp bottom
  121.   "Appended " paste endline ".qm to current macros"          *  w/ date/time
  122.    unmarkblock savefile macroread "dum4.mac" return          * read apnd. macfil
  123. *
  124. * 288 bytes Thu  07-26-1990  02:17:16
  125. * 273 bytes Fri  09-14-1990  14:05:47
  126.  
  127.  
  128.  
  129.  
  130. *┌───────────────────────────────────────────────────────────┐
  131. *│(Alt_4) Appends txtfile [file].qm  to a "standard" txtfile │
  132. *│     named macros.qm and reads appended macfile.           │
  133. *└───────────────────────────────────────────────────────────┘
  134. *  Remember to modify "g:\qe\macros" (no extension) in this
  135. *  macro to your "standard" macfile.
  136. *
  137. @4 macrobegin
  138.    unmarkblock                                               * unmarkblock
  139.    savefile DOS "qmacTA2 " currentfilename                   * make file.mac
  140.    backspace backspace backspace " "                         *
  141.   "g:\qe\macros" return   **(no EXTension)**                 **
  142.    begline insertline dropanchor currentfilename             * get name to scrch
  143.    storescrbuff "1" return cut                               *
  144.    editfile "c:!" return quit                                * quit c:!
  145.    editfile paste  return horizontalwindow                   * load file.qm
  146.    editfile "c:!" return                                     * get error file
  147.    insertdate  inserttime                                    * put date in c:!
  148.    find "(" return return
  149.  jfalse NOERROR:                                             * get error line #
  150.    wordright unmarkblock markblockbegin wordright            *
  151.    cursorleft markblockend copy savefile prevwindow          *
  152.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  153.  jump CONTINUE:                                              *
  154.  NOERROR:                                                    *
  155.    prevwindow zoomwindow                                     * no error, go to
  156.  CONTINUE:
  157.    editfile "c:$" return quit                                *
  158.    editfile       return killfile                            * load dum3.qm
  159.    editfile "dum3.qm"    return quit
  160.    editfile              return                              * load dum3.qm
  161.    begfile cursordown endline                                * stamp
  162.    cursorright
  163.   "from:" cursorright
  164.    getscrbuff "1" return
  165.    unmarkblock endfile return                                * line on bot
  166.   "*" cursorright "Tom Hogshead"
  167.    cursorright cursorright
  168.    insertdate inserttime                                     * - name/date bot
  169.   "Appnd:" cursorright
  170.    getscrbuff "1" return unmarkblock                         * - file on bot
  171.    savefile macroread currentfilename                        * read dum3.mac
  172.    backspace backspace "MAC" return                          *
  173. *
  174. * 251 bytes Thu  07-26-1990  09:00:10
  175. * 228 bytes Fri  09-14-1990  14:05:51
  176.  
  177.  
  178.  
  179.  
  180. *┌──────────────────────────────────────────────────────────────┐
  181. *│(Alt_5) Gets error file (c:!) in window. Press ENTER to remove│
  182. *└──────────────────────────────────────────────────────────────┘
  183. *
  184. @5  macrobegin
  185.     horizontalwindow                                         * make window
  186.     editfile "c:!" return                                    * load c:!
  187.     makectrofscreen pause zoomwindow                         * zoom on pause
  188.     quit                                                     * quit c:!
  189. *
  190. * 30 bytes Thu  07-26-1990  09:03:05
  191. * 17 bytes Fri  09-14-1990  14:05:55
  192.  
  193.  
  194.  
  195. * ┌────────────────────────────────────────────┐
  196. * │ (Alt_6) Makes textfile from current macros │
  197. * └────────────────────────────────────────────┘
  198. *
  199. @6 macrobegin
  200.    macrowrite "c:$.mac" return return   * write to c:$.mac
  201.    DOS  "qmact c:$"     return return   * make c:$.qm
  202.    editfile   "c:$.qm"  return quit     * quit old c:$.qm
  203.    editfile return                      * load new c:$.qm
  204.    killfile                             * kill c:$.qm
  205.    endfile                              * to see newest macro
  206. *
  207. * 61 bytes Sat  09-15-1990  14:26:40
  208.  
  209.  
  210.  
  211.  
  212. *┌───────────────────────────────────────────────────────────┐
  213. *│ (Alt_7) Copies txtfile [file].QM to dummy txtfile.        │
  214. *│  Makes and reads macfile.                                 │
  215. *└───────────────────────────────────────────────────────────┘
  216. *
  217. @7 macrobegin
  218.    unmarkblock writeblock "c:$.qm" return                    * copy file.qm
  219.    begline insertline dropanchor currentfilename             * get name
  220.    storescrbuff "1" return cut                               *   to scratch
  221.    editfile "c:$.qm" return quit editfile return             * load c:$.qm
  222.    DOS "qmacbj c:$" return                                   * make c:$.mac
  223.    begline insertline dropanchor currentfilename cut         * get name to scrap
  224.    editfile "c:!" return quit                                * quit c:!
  225.    editfile paste return horizontalwindow                    * load file.qm
  226.    editfile "c:!" return                                     * load error file
  227.    insertdate  inserttime                                    * put date in c:!
  228.    find "(" return return                                    *
  229.  jfalse NOERROR:                                             * get error line #
  230.    wordright unmarkblock markblockbegin wordright            *
  231.    cursorleft markblockend copy savefile prevwindow          *
  232.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  233.  jump CONTINUE:                                              *
  234.  NOERROR:                                                    *
  235.    prevwindow zoomwindow                                     * no error, back
  236.  CONTINUE:                                                   *
  237.    DOS "qmact c:$" return return                             * make c:$.qm
  238.    editfile "c:$.qm" return quit editfile return             * load c:$.qm
  239.    endfile addline                                           *
  240.    "*" insertdate inserttime                                 * - name/date bot
  241.    getscrbuff "1" return unmarkblock                         * - file on bot
  242.    killfile                                                  * kill c:$.qm
  243.    macroread currentfilename                                 * read c:$.mac
  244.    backspace backspace "MAC" return                          *
  245. *
  246. * 194 bytes Thu  08-21-1980  19:54:29
  247. * 184 bytes Fri  09-14-1990  14:06:03
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256. *┌───────────────────────────────────────────────────────────┐
  257. *│ (Alt_t) Copies txtfile [file].QM to dummy txtfile.        │
  258. *│  Makes and reads macfile, small version                   │
  259. *└───────────────────────────────────────────────────────────┘
  260.  
  261. * This is an alternate version of @7. Errors during macro conversion are
  262. * not saved in an error window. It is much smaller than @7.
  263.  
  264. @t      MacroBegin                      *
  265.         unmarkblock                     *
  266.         WriteBlock "c:$.qm"     Return  * copy file/block to temp file
  267.         DOS  "qmacb c:$" Return Return  * make temp macfile
  268.         DOS  "qmact c:$" Return Return  * make temp txtfile
  269.         EditFile   "c:$.qm" Return Quit * quit temp file from ring
  270.         EditFile Return                 * load temp txtfile
  271.         killfile                        * kill temp file
  272.         MacroRead "c:$.Mac" Return      * read temp macfile
  273. *
  274. * 95 bytes Fri  09-14-1990  14:06:07
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281. *┌───────────────────────────────────────────────────────────┐
  282. *│(Alt_8) READS macfile from txtfile [file].QM               │
  283. *└───────────────────────────────────────────────────────────┘
  284. *
  285. @8 macrobegin
  286.    macroread currentfilename backspace backspace "mac" return
  287. *
  288. * 15 bytes Thu  07-26-1990  02:18:38
  289. * 15 bytes Fri  09-14-1990  14:06:11
  290.  
  291.  
  292.  
  293.  
  294. *┌───────────────────────────────────────────────────────────┐
  295. *│(Alt_9) Makes macfile from txtfile [file].QM, NO read      │
  296. *└───────────────────────────────────────────────────────────┘
  297. *
  298. @9 macrobegin savefile DOS "qmacb " currentfilename           * make file.mac
  299.    backspace backspace backspace return                       * remove ".qm"
  300. *
  301. * 23 bytes Thu  07-26-1990  02:18:56
  302. * 23 bytes Fri  09-14-1990  14:06:14
  303.  
  304.  
  305.  
  306.  
  307. *┌───────────────────────────────────────────────────────────┐
  308. *│(Alt_0) Makes macfile from txtfile [file].QM               │
  309. *│   Loads macfile [file].MAC, With error window.            │
  310. *└───────────────────────────────────────────────────────────┘
  311. *                   
  312. @0 macrobegin
  313.    savefile DOS "qmacbj " currentfilename                    * make file.mac
  314.    backspace backspace backspace return                      *
  315.    unmarkblock insertline begline                            * insert temp line
  316.    dropanchor currentfilename cut                            * cut name to scrap
  317.    editfile "c:!" return quit                                * quit c:!
  318.    editfile paste return horizontalwindow                    * load file.qm
  319.    editfile "c:!" return                                     * get error file
  320.    insertdate  inserttime                                    * put date in c:!
  321.    find "(" return return                                    * get error line #
  322.  jfalse NOERROR:                                             *
  323.    wordright unmarkblock markblockbegin wordright            *
  324.    cursorleft markblockend copy savefile prevwindow          *
  325.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  326.  jump CONTINUE:                                              *
  327.  NOERROR:                                                    *
  328.    prevwindow zoomwindow                                     * no error, back
  329.  CONTINUE:                                                   *
  330.    macroread currentfilename backspace backspace "mac" return* read new macro
  331. *
  332. * 98 bytes Thu  07-26-1990  09:08:31
  333. * 93 bytes Fri  09-14-1990  14:18:31
  334.  
  335.  
  336.  
  337.  
  338. *┌───────────────────────────────────────────────────────────┐
  339. *│(Alt_q) Makes macfile from txtfile [file].QM               │
  340. *│   Loads macfile [file].MAC, NO error window, SMALL.       │
  341. *└───────────────────────────────────────────────────────────┘
  342. *                   
  343. @q macrobegin
  344.    savefile DOS "qmacb " currentfilename                     * make file.mac
  345.    backspace backspace backspace return return               *
  346.    macroread currentfilename backspace backspace "mac" return* read new macro
  347. *
  348. * 35 bytes Fri  09-14-1990  14:06:22
  349.  
  350.  
  351.  
  352.  
  353. *┌───────────────────────────────────────────────────────────────────┐
  354. *│(Alt_h) Finds first word on cursor line marked in document below   │
  355. *└───────────────────────────────────────────────────────────────────┘
  356. *
  357. *        Alt_h macro has 2 steps:
  358. *
  359. *        1. Press Alt and h at the same time. An ! shows at the
  360. *        end of the top line. Cursor down to desired line in Index.
  361. *
  362. *        2. Press Enter. The macro first erases the !, and
  363. *        then finds the first word on the cursor line in the document
  364. *        below marked with (...).
  365. *
  366. *
  367. @h macrobegin
  368.         unmarkblock                     * unmark any marked blocks
  369.         begfile endline                 * go to file begin endline
  370.         "!"                             * put ! at endline
  371.         begline
  372.         find "!" return return begline  * highlight !
  373.         pause                           * pause for Index selection
  374.         wordright markword              * mark first word on line
  375.         copy                            * copy word to scrap buffer
  376.         begfile                         * begfile
  377.         find "!" return return delch    * find & delete !
  378.         endpara                         * go to end of Index
  379.         makectrofscreen                 * cursor line center of window
  380.         find "(" paste ")"
  381.         return "I" return               * find first marked word in doc
  382.  jfalse NOMARK:
  383.         begline                         * if mark found go to begline
  384.  jump END:
  385.  NOMARK:
  386.         begfile                         * if no mark found go to begfile
  387.  END:
  388. *
  389. * 47 bytes Thu  07-26-1990  13:02:27
  390. * 47 bytes Fri  09-14-1990  14:06:26
  391.  
  392.  
  393.  
  394.  
  395. * ┌────────────────────────────────────┐
  396. * │(Alt_f1) Makes single column macro  │
  397. * └────────────────────────────────────┘
  398.  
  399. * If a macro is not a marked block, the full txtfile is made into a
  400. * single column macro.
  401. *
  402. * To  make a single column macro with Alt_f1, place the cursor line
  403. * anywhere in a macro txtfile (after loading the macfile) and press Alt
  404. * and f1 at the same time.
  405.  
  406. @f1 macrobegin
  407.         writeblock "c:$.qm" return      * copy block or file to c:$.qm
  408.         unmarkblock insertline begline  * insert temp line
  409.         dropanchor currentfilename cut  * cut currentfilename to scrap
  410.         DOS "qmacb c:$"  return  return * make macfile
  411.         DOS "qmact-n c:$" return return * make txtfile
  412.         editfile "c:$.qm" return quit   *
  413.         editfile return                 * load c:$.qm
  414.         endfile addline                 * insert blank line at end
  415.         "* " insertdate inserttime      * for date/time
  416.         paste unmarkblock               * get file name on line
  417.         killfile                        * kill c:$.qm
  418. *
  419. * 98 bytes Fri  09-14-1990  14:06:30
  420.  
  421.  
  422.  
  423.  
  424. *┌──────────────────────────────────────────┐
  425. *│ (Alt_f2) Puts key beside single command  │
  426. *└──────────────────────────────────────────┘
  427.  
  428. * To get the key for a single command in a macro, place the cursor line
  429. * on the command in a single column macro txtfile and press Alt_f2. The
  430. * key corresponding to the command will be listed next to the commmand.
  431.  
  432.  
  433. @f2 macrobegin
  434.         unmarkblock insertline begline  * insert temp line
  435.         dropanchor currentfilename      *
  436.         storescrbuff "1" return         * get to scrbuff
  437.         cut                             * delete temp line
  438.         begline wordright markword      * get to command, mark it
  439.         copy                            * get to scrap
  440.         unmarkblock                     * unmark
  441.         editfile                        *
  442.        "g:\qe\qconfig.dat"             ** CHANGE for your setup **
  443.         return                          * load qconfig.dat
  444.         begfile                         * go to begin qconfig.dat
  445.         FIND "         "                * insert 8 spaces before find | 2.8
  446.         paste                           * paste command for find
  447.         return "IW" return              * find command in qconfig.dat
  448.  jfalse NOFIND:                         * mark if found, quit if not
  449.         wordright markcolumn            * move cursor to command
  450.         begline                         * go to  begline
  451.        "* "                             * insert asterisk space
  452.         begline markcolumn              * go to begline, include key
  453.         storescrbuff "2" return         * get key to scrbuff
  454.         cursordown                      * move down line
  455.         unmarkblock                     * unmark command
  456. *        quit                            * quit qconfig.dat
  457.         getscrbuff "1" return           * get currentfilename
  458.         cut                             * cut currentfilename
  459.         editfile paste return           * load currentfilename
  460.         markcolumn                      * start to mark block
  461.         gotocolumn "33" return          * postition to get key
  462.         getscrbuff "2" return           * get key
  463.         begline                         * go to begline
  464.         makectrofscreen                 * for better viewing
  465.         cursordown                      * move down to next command
  466.  jump END:                              * stop after getting key
  467.  NOFIND:                                * come here if no key for command
  468.         getscrbuff "1" return           * get currentfilename
  469.         cut                             * cut currentfilename
  470.         editfile paste return           * return to file
  471.         gotocolumn "33" return          * position to get key
  472.         "* "                            * insert asterisk space
  473.         cursordown                      * move down to next command
  474.         begline                         *
  475.  END:                                   *
  476. *
  477. * 136 bytes Fri  09-14-1990  14:06:35
  478. * 145 bytes Mon  02-18-1991  12:32:15 changed 4 to 8 spaces
  479.  
  480.  
  481.  
  482.  
  483.  
  484. *┌────────────────────────────────────────────────────────────────┐
  485. *│ (Alt_f3) Puts key beside ALL commands in single column macfile │
  486. *└────────────────────────────────────────────────────────────────┘
  487.  
  488. * To get the keys for ALL commands in a macro, place the cursor
  489. * line at the top of a macro txtfile and press Alt_f3. An example of
  490. * this output is shown at the end of this macro. The keys corresponding
  491. * to each command will be listed also in a single column next to the
  492. * command.
  493.  
  494. @f3 macrobegin
  495.         unmarkblock insertline begline  * insert temp line
  496.         dropanchor currentfilename      *
  497.         storescrbuff "1" return         * 
  498.         cut                             * delete temp line
  499.  START:                                 *
  500.         endline begline                 * line blank? if so end
  501.  jfalse END:                            *
  502.         begline wordright markword      *
  503.         copy unmarkblock                * get command to scrap, unmark
  504.         editfile                        *
  505.        "g:\qe\qconfig.dat"             ** CHANGE for your setup **
  506.         return                          * load qconfig.dat
  507.         begfile                         * go to begin qconfig.dat
  508.         FIND "         "                * insert 8 spaces before find | 2.8
  509.         paste                           * paste command for find
  510.         return "IW" return              * find command in qconfig.dat
  511.  jfalse NOFIND:                         * mark if found, quit if not
  512.         wordright markcolumn begline    * move cursor to command
  513.        "* " begline markcolumn          * insert asterisk space
  514.         storescrbuff "2" return         * get key to scratch
  515.         cursordown unmarkblock          * move down line, unmark command
  516.         quit                            * quit qconfig.dat
  517.         getscrbuff "1" return           * get currentfilename
  518.         cut                             * cut currentfilename
  519.         editfile paste return           * load currentfilename
  520.         markcolumn                      * start to mark block
  521.         gotocolumn "33" return          * postition to get key
  522.         getscrbuff "2" return           * get key
  523.         begline makectrofscreen         * for better viewing
  524.         cursordown                      * move down to next command
  525.  jump START:                            * start on next command
  526.  NOFIND:                                * come here if no key for command
  527.         getscrbuff "1" return           * get currentfilename
  528.         cut                             * cut currentfilename
  529.         editfile paste return           * return to file
  530.         gotocolumn "33" return          * position to get key
  531.         "* "                            * insert asterisk space
  532.         cursordown                      * move down to next command
  533.         begline                         *
  534.  jump START:                            * do next line till done
  535.  END:                                   *
  536. *
  537. * 144 bytes Fri  09-14-1990  14:06:40
  538. * 154 bytes Mon  02-18-1991  12:32:44 changed 4 to 8 spaces
  539.  
  540. *-----------------
  541. * Here is what the macro Alt_f1 looks like by first marking it as a
  542. * block, then running @f1 by placing the cursor line on the line
  543. * below @f1 in c:$.qm and running @f3. (NOTE: an asterisk and
  544. * space have been added to column 1)
  545.  
  546. * *
  547. * * Converted by QMAC from: c:\$.mac
  548. * *
  549. * @f1     Macro_Begin                    <- (modified for SIZE macro)
  550. *         WriteBlock              * @w
  551. *         "c:$."                  *
  552. *         "qm"                    *
  553. *         Return                  * enter
  554. *         UnmarkBlock             * @u
  555. *         InsertLine              * ^n_i
  556. *         BegLine                 * home
  557. *         DropAnchor              * @a
  558. *         CurrentFilename         * ^n_n
  559. *         Cut                     * ^c_u
  560. *         DOS ""                  * ^n_o
  561. *         "qmacb "                *
  562. *         "c:$"                   *
  563. *         Return                  * enter
  564. *         Return                  * enter
  565. *         DOS ""                  * ^n_o
  566. *         "qmact-"                *
  567. *         "n c:$"                 *
  568. *         Return                  * enter
  569. *         Return                  * enter
  570. *         EditFile                * f3
  571. *         "c:$."                  *
  572. *         "qm"                    *
  573. *         Return                  * enter
  574. *         Quit                    * @x
  575. *         EditFile                * f3
  576. *         Return                  * enter
  577. *         EndFile                 * ^pgdn
  578. *         AddLine                 * ^n_j
  579. *         "* "
  580. *         InsertDate              * ^d
  581. *         InsertTime              * ^e
  582. *         Paste                   * ^c_p
  583. *         UnmarkBlock             * @u
  584. *         KillFile                * ^k_z
  585. *
  586. * * Thu  09-13-1990  13:03:03 e:\up\getc13.qm
  587.  
  588.  
  589.  
  590.  
  591.  
  592.  
  593.  
  594. * ┌───────────────────────────────────────────────────────────────┐
  595. * │ (Alt_f4) Retrieves a command and it's key from QCONFIG.DAT    │
  596. * └───────────────────────────────────────────────────────────────┘
  597.  
  598. * This macro retrieves a command or all commands matching a selected
  599. * find criteria from your QCONFIG.DAT file, displays the selected
  600. * command(s) and it's key on the screen, and then removes the
  601. * command(s) and it's key from the screen. For those of us who can
  602. * never remember all the commands and can never find our reference
  603. * sheet, this might help.
  604.  
  605. * To run, press Alt_f4, then enter the first letter (or more) of the
  606. * command you want to know the key for, press 'Enter' to see the the
  607. * command(s) and it's key, then press 'Enter' again to remove the
  608. * command(s) and it's key from the screen.
  609. *
  610. * For example, to find the key for appendscrbuff, press:
  611. *                     <Alt_f4>
  612. *                      app
  613. *                     <Enter>
  614. *
  615. * You should see the following highlighted on your screeen:
  616. *
  617. *                                               |
  618. * ^b_a            appendscrbuff                 |
  619. *
  620. *
  621. * Entering "b" instead shows all commands beginning with "b":
  622. *
  623. *                                               |
  624. * ^h              backspace                     |
  625. * ^home           begscreen                     |
  626. * ^pgup           begfile                       |
  627. * home            begline                       |
  628. * backspace       backspace                     |
  629. *
  630. *
  631. * Press 'Enter' to remove the command(s) and it's key from the screen,
  632. * or press 'Esc' three times if you want to keep the command(s) on the
  633. * screen for reference.
  634.  
  635. @f4 macrobegin
  636.         unmarkblock insertline begline  * insert temp line
  637.         dropanchor currentfilename      *
  638.         cut                             * delete temp line
  639.         editfile                        *
  640.        "g:\qe\qconfig.dat"             ** CHANGE for your setup **
  641.         dropanchor                      * start to clear scrap
  642.         storescrbuff "1" return         * get to scrap
  643.         unmarkblock begfile             * go to begin qconfig.dat
  644.         FIND "         "                * insert 8 spaces before find | 2.8
  645.         pause                           * pause for command to find
  646.         return "i" return               * find first command
  647.   jump NEXT:                            *
  648.   START:                                * come here more than 1 find
  649.         find return "i" return          * find next command
  650.   NEXT:                                 *
  651.   jfalse FINISH:                        * mark if found, quit if not
  652.         markline begline                * mark command line
  653.        "* "                             *   asterisk space
  654.         appendscrbuff "1" return        * get to scrbuff
  655.         cursordown unmarkblock          * move down line, unmark command
  656.   jump START:                           * see if any more matches
  657.   FINISH:                               * come here after last find
  658.         quit                            * quit qconfig.dat
  659.         editfile paste return           * return to file
  660.         markcolumn                      * start to mark block
  661.         getscrbuff "1" return           * get command and key
  662.         delline begline                 * delete blank line, begline
  663.         maketopofscreen                 * for better viewing
  664.         pause                           * pause, then 'Enter' to..
  665.         deleteblock                     * clean up, remove block
  666. *
  667. * 106 bytes Fri  09-14-1990  14:06:49
  668. * 116 bytes Mon  02-18-1991  12:46:36
  669.  
  670. * (Other) Macros available: See ALLMACRO.INF.
  671. *
  672.  
  673. * (Version) History:
  674. *
  675. * 1.0  -  initial version
  676. * 1.1  -  Changed Alt-6 to keep [file].qm in ring after running.
  677. * 1.2  -  Date & time stamp put in dum.qm (Alt-6, Alt-7).
  678. * 1.3  -  Added batch files to macro13.ZIP.
  679. * 1.4  -  Changed Alt-6 & 7 to stamp [file].QM translated from.
  680. *      -  Changed Alt-0 to not pause if no errors.
  681. *      -  Added Alt-5 to see error files in window.
  682. *      -  Changed /W60 to /W70 and removed "pause" in qmact.bat.
  683. * 1.5  -  Changed Alt-7 to not pause if no errors.
  684. * 1.6  -  Shortened Alt-6, 7 & 10. Faster & no pause now if no errors.
  685. * 1.7  -  Corrected Alt-6 to write macros first. Sorry.
  686. * 1.8  -  Added Alt-4 to append text file [file].qm  macros
  687. *         to a "standard" macro and read appended macro.
  688. * 1.9  -  Added Alt-3 to merge designated macro [file].mac
  689. *         with current macros. QEdit normally overwrites
  690. *         current macros when reading a new macro.
  691. * 2.0  -  Added Alt-2 to refresh macro buffer with "standard" macro.
  692. *      -  New qmacTA2.bat for Alt-4, gets "standard" name as %2.
  693. *      -  Added Alt T & Alt N to select txtfile to read from
  694. *         sorted list of all avaialable txtfiles in directory.
  695. *      -  New SORT-T.BAT and SORT-F.BAT for Alt T & N to sort macro list.
  696. *      -  Changed Alt-4 to identify "standard" rather than batch file.
  697. *         (Modify g:\qe\macros for the name of your "standard" macro.)
  698. *      -  Shortened Alt-3,7 & 0, total 91 bytes. (Important when merging
  699. *         since QEdit macro buffer is limited to 2046 bytes macros.)
  700. *      -  Moved macroread to end of Alt-3. No problem, just in case.
  701. *         (Reading macros while executing can sometimes cause problems.)
  702. *      -  Changed Alt-5 to refresh c:!.
  703. * 2.1  -  (Internal)
  704. * 2.2  -  Added Alt-1 to select txtfile to load from list of all txtfiles
  705. *         in directory sorted by Name. Added sort-N2.bat for this macro.
  706. *      -  Changed Alt T & Alt N to select macfile, not txtfile as v2.0,
  707. *         from sorted list of all available macfiles in directory.
  708. *      -  Changed sort-T.bat, sort-N.bat and sort-N1.bat for macrs.
  709. *      -  Renamed MACCMTxx to MACROxx. Dropped MACCMTxx. Macros comments
  710. *         and instructions are now are in MACROxx.qm.
  711. *      -  Shortened highlight bar in Alt N,t. Saves ~30 bytes/macro.
  712. *      -  Changed dum.dir to $ in Alt-4 & qmacTA2.bat to shorten
  713. *      -  Added killfile to Alt-3 & 4. Changed endfile display in Alt-4.
  714. *      -  Replaced "j:\j" with "c:!" in macros and batch files to shorten.
  715. *      -  Changed qmacTA2.bat for better display.
  716. *      -  Changed select window from "c:!" to "c:$" in batch files
  717. *      -  Sort batch files (sort-xx.bat) also changed.
  718. * 2.3  -  Changed  @5 to keep error file c:! in ring.
  719. *      -  By removing " "'s, changing file name tracking in buffers,
  720. *         and shortening header and footer labels:
  721. *               - shortened @4        28 bytes
  722. *               - shortened @5         5  "
  723. *               - shortened @6        67  "
  724. *               - shortened @7        24  "
  725. *               - shortened @9         3  "
  726. *      -  Added macro size 'bytes line' at end of each macro
  727. * 2.4  -  Removed dum.qm and dum.mac from zip package
  728. *      -  Shortened Alt_6 from 147 to  54 bytes
  729. *      -  Shortened Alt_7 from 258 to 194 bytes
  730. * 2.4a -  Modified @6 and description
  731. * 2.4b -  Modified documentation.
  732. * 2.4c -  Changed file name from MACROxx to MACRxx.
  733. * 2.5  -  Changed j:j to c:! in macros and batch files.
  734. *      -  Changed down arrow #25 to ! in ^0.
  735. *      -  Changed .LST and .QL files.
  736. *      -  Removed @1, @t and @n. Newer macros to do the same thing
  737. *         are in FILExx.ZIP.
  738. * 2.6  -  Added @t, smaller faster version of @7.
  739. *      -  Added @q, smaller faster version of @0.
  740. *      -  Added @f1, @f2, @f3 and @f4 from GETCxx.ZIP and COLxx.ZIP,
  741. *         which are no longer included as seperate files, but are now
  742. *         a part of MACRxx.ZIP.
  743. *      -  Modified and shortened all but @2, @6, @8, @9 and ^1.
  744. *      -  Added killfile to @6 so writeblock return works correctly.
  745. * 2.6a -  Changed ^1 help macro key to @h key.
  746. * 2.7  -  Removed [d:]\[path] for location of QMAC from QMACxxx batch
  747. *         files. QMAC can be located anywhere in path.
  748. * 2.7a -  Modified documentation and added START.BAT.
  749. *      -  Change MACRO file names to MACR.
  750. * 2.7b -  Corrected @h Index Use instructions.
  751. * 2.8  -  Changed 4 to 8 spaces in Find for @f2 - @F4 to correctly
  752. *         find command and key.
  753.  
  754. * error_sample, remove asterisk to test for errors
  755. *
  756. * Tom Hogshead  Mon  02-18-1991
  757.